home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Generous Efforts of Many
/
gemcd.zip
/
GEM.CD.A.po
/
FEATURES:BEAGLE
/
UTIL.CITY.SHK
/
UTILITY.CITY
/
TEST PATTERNS.bas
< prev
next >
Wrap
BASIC Source File
|
2000-01-01
|
3KB
|
47 lines
30 TEXT : HOME : VTAB 10: HTAB 11: POKE 32,10
40 PRINT "APPLE ][ TEST PATTERNS": PRINT "----------------------": PRINT : PRINT "<1> HI-RES": PRINT "<2> LO-RES": PRINT : PRINT " SELECT:";: GET A$: PRINT A$: TEXT
45 IF A$ < >"1" AND A$ < >"2" THEN TEXT : GOTO 30
46 IF A$ = "2" THEN 500
50 REM <CTRL-M>===================<CTRL-M>HI-RES TEST PATTERN<CTRL-M>BY BERT KERSEY<CTRL-M>BEAGLE BROS.<CTRL-M>===================<CTRL-M><CTRL-M>
60 ONERR GOTO 220
70 GOSUB 230
80 POKE -16304,0: POKE -16297,0: HGR
90 HOME : VTAB 21: PRINT " 0 1 2 3 4 5 6 7 BLK GRN VLT WHT BLK RED BLU WHT"
100 PRINT : HTAB 10: PRINT "APPLE ][ HI-RES COLORS";: VTAB 1
110 FOR X = 0 TO 245 STEP 35
120 HCOLOR= INT(X/35)
130 FOR I = X TO X +34
140 HPLOT I,0 TO I,159: NEXT
150 NEXT
160 VTAB 23: HTAB 1: PRINT "]";: FLASH : PRINT " ";: NORMAL : VTAB 1
170 GET A$: PRINT A$: HOME
180 N = 1: VTAB 23: HTAB 1: PRINT "]";: GOTO 200
190 N = N +1: VTAB 1: HTAB 1: GET A$: PRINT A$: VTAB 23: HTAB 1 +N - INT(N/40) *40
200 PRINT MID$ (X$,N,1);: VTAB 23: FLASH : PRINT " ";: NORMAL : PRINT " ";: IF MID$ (X$,N,1) < >"'" THEN FOR I = 1 TO 3:S = PEEK(U): NEXT
210 GOTO 190
220 POKE -16368,0: VTAB 1: GET A$: PRINT A$: GOTO 80
230 X$ = "THIS'IS'APPLE'][.'I'HAVE'TAKEN'CONTROL.YOU'WILL'DO'WHAT'I'SAY.''PUT'$1000'IN'ANENVELOPE'AND'GO'TO'THE'COMPUTER'STORE.''BUY'ME'A'LARGE'BAG'OF'MEMORY'CHIPS.'''''I'WILL'WAIT'HERE.''''P.S.'WHATEVER'YOU''DO,'DO'NOT'TURN'OFF'THE'POWER"
240 X$ = X$ +".''''''''''''''''''''''''''":U = -16336: RETURN
500 REM <CTRL-M>===================<CTRL-M>LO-RES TEST PATTERN<CTRL-M>BY BERT KERSEY<CTRL-M>BEAGLE BROS.<CTRL-M>===================<CTRL-M><CTRL-M>
510 GR : HOME :Q = -16384
520 REM NAMES & NUMBERS: ----------------
540 A$ = " 1 2 4 8 5 3 6 9 12 7 11 13 14 MAGDRKDRKBRN&10LAVMEDORGBRTLITPNKYELAQU BLUGRN GRY BLU GRNBLU "
550 FOR V = 21 TO 23: FOR I = 1 TO 37 STEP 3:T = 40 *(V -21) +I:IMOD = I - INT(I/6) *6: IF IMOD <4 AND IMOD >0 THEN INVERSE
560 VTAB V: HTAB I +1: PRINT MID$ (A$,T,3 - INT((V +I)/61));: NORMAL : NEXT I,V
570 HTAB 1: PRINT ">PRESS ANY KEY. (0=BLACK; 15=WHITE";: POKE 2039, ASC(")") +128: COLOR= 7: PLOT 0,47
580 FOR J = 0 TO 12:X = 3 *J
590 REM CLASSIFY BY B/W SHADE: ----------------------
600 IF J <5 THEN COLOR= 2 ^J -6 * INT(J/4)
610 IF J >4 THEN COLOR= 3 *(J -4)
620 IF J >8 THEN COLOR= 15 -2 ^(12 -J)
630 FOR I = X +1 TO X +3: VLIN 0,39 AT I: NEXT I: NEXT J
635 IF R = 6 THEN HOME : VTAB 21: HTAB 2: INVERSE : PRINT " 1 2 4 8 ";: NORMAL : PRINT "5 ";: INVERSE : PRINT " 3 6 9 12 ";: NORMAL : PRINT " 7 11 13 14 ";: INVERSE : HTAB 2: PRINT " DARK... ";: NORMAL : PRINT "&10";: INVERSE : PRINT " MEDIUM... ";
636 IF R = 6 THEN NORMAL : PRINT " LIGHT... ";: HTAB 14: PRINT "SOLID": HTAB 2: INVERSE : PRINT " APPLE GREY SCALE ";
640 REM SEPARATE COLORS: ----------------
650 IF PEEK(Q) <136 THEN 650
660 POKE Q +16,0:R = R +1: IF R >6 THEN R = 0
665 IF R = 0 THEN 520
670 ON R +1 GOTO 580,690,700,680,690,700,580
680 GOTO 580
690 FOR X = 1 TO 37 STEP 3: COLOR= 15 * INT(R/3): VLIN 0,39 AT X +2: NEXT X: GOTO 650
700 FOR X = 1 TO 37 STEP 3: VLIN 0,39 AT X: NEXT X: GOTO 650